Public Function GetOrders(ByRef OrderArray() As OrderDetails, QueryString As String) As Boolean
    
    On Error GoTo errorHandler
    
    '\\ Adds a new customer to the local database.
    
    Dim dbConnection    As ADODB.Connection
    Dim dbRecordSet     As ADODB.Recordset
    Dim intLoopIndex    As Integer
    
    If Len(Application.LocalDBConnection) < 1 Then
    
        MsgBox "No local database connection parameter provided. Please run the configuration utility. Unable to get orders.", 48, "Warning"
        
        Exit Function
        
    End If
    
    Set dbConnection = New ADODB.Connection
    Set dbRecordSet = New ADODB.Recordset
    
    'Connect to the database
    dbConnection.ConnectionString = Application.LocalDBConnection
    dbConnection.Open
    
    'Build SQL command
    With dbRecordSet
        
        .Open "SELECT * FROM tbl_orders WHERE " & QueryString, dbConnection, adOpenStatic, adLockReadOnly
        
        If Not (.RecordCount < 1) Then
            
            ReDim OrderArray(.RecordCount - 1)
            
            intLoopIndex = 0
            
            .MoveFirst
            
            Do
            
                OrderArray(intLoopIndex).Customer = .Fields("Customer").Value
                OrderArray(intLoopIndex).CustOrdNo = .Fields("CustOrdNo").Value
                OrderArray(intLoopIndex).Description = .Fields("Description").Value
                OrderArray(intLoopIndex).User = .Fields("User").Value
                OrderArray(intLoopIndex).Total = .Fields("Total").Value
                OrderArray(intLoopIndex).InsertDate = .Fields("InsertDate").Value
                
                .MoveNext
                
                intLoopIndex = (intLoopIndex + 1)
                
            Loop Until (.EOF)
            
            GetOrders = True
        
        End If
        
    End With
    
    'Close recordset and connection
    If (dbRecordSet.State = adStateOpen) Then
        
        dbRecordSet.Close

    End If
    
    If (dbConnection.State = adStateOpen) Then
        
        dbConnection.Close
    
    End If
    
    'Dispose of DB objects
    Set dbConnection = Nothing
    Set dbRecordSet = Nothing
        
    Exit Function
    
errorHandler:
    
    'Close recordset and connection
    If (dbRecordSet.State = adStateOpen) Then
        
        dbRecordSet.Close

    End If
    
    If (dbConnection.State = adStateOpen) Then
        
        dbConnection.Close
    
    End If
    
    'Dispose of DB objects
    Set dbConnection = Nothing
    Set dbRecordSet = Nothing
    
    ShowError Err, "modFunctions.GetOrders()"

End Function