Sub Send_Files()
'Working in 2000-2007
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range, FileCell As Range, rng As Range
 
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With
 
    Set sh = Sheets("Sheet1")
 
    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
 
    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)
 
        'Enter the file names in the C:E column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:E1")
 
        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)
 
            With OutMail
                .To = cell.Value
                .Subject = cell.Offset(0, 4).Value
                .Body = cell.Offset(0, -1).Value & vbNewLine & vbNewLine & _
                "Please find attached your reports. Should you have any questions please let me know." & vbNewLine & vbNewLine & _
                "Regards" & vbNewLine & vbNewLine & _
                "Chris Durant" & vbNewLine & _
                "Senior Reporting Analyst" & vbNewLine & _
                "Planning Team - Strategy And Marketing" & vbNewLine & _
                "RBS Insurance,3rd Floor, Phase 2, Churchill Court, Bromley, MP 41" & vbNewLine & _
                "Ext: 0208 313 5542" & vbNewLine & vbNewLine & vbNewLine & _
                ""
                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
 'THIS IS WHERE IT SOMETIMES READS THE FILE NAMES AS FILECELL.VALUE BUT THE ABOVE IF STATEMENT READS AS FALSE (GOES TO ENDIF)
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell
                .display  'Use Display or Send 
            End With
 
            Set OutMail = Nothing
        End If
    Next cell
 
    Set OutApp = Nothing

    With Application
        .DisplayAlerts = True
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub