DROP table dbo.Child
create table dbo.Child(
	ParentId	INT	not null,
	SEQ_NO		INT	not null,
	aColumn		INT,
	Qty		INT	not null,
	constraint PK_Child primary key (ParentId, SEQ_NO)
)

/*PARENT TABLE*/
DROP table dbo.Parent
create table dbo.Parent (
	ParentId	INT	not null,
	TotalQty	INT	NOT null	DEFAULT 0,
	constraint PK_Parent primary key (ParentId)
)

ALTER table dbo.Child
	ADD constraint FK_child_parent foreign key (ParentId) 
		references dbo.Parent (ParentId)
GO

CREATE TRIGGER ChildTrigger
ON Child
FOR INSERT, UPDATE, DELETE
AS
BEGIN
	WITH Changed AS	-- get all DISTINCT ParentId's whose Child records 
			-- have changed somehow (either by an INSERT, UPDATE 
			-- or DELETE)
	(SELECT inserted.ParentId FROM inserted
		UNION
	SELECT deleted.ParentId FROM deleted
	),
	Summary AS	-- recalculate TotalQty of all Parents whose Children 
			-- have changed
	(SELECT C.ParentId, SUM(C.Qty) AS SumQty
	FROM Changed 
		INNER JOIN dbo.Child as C ON
			Changed.ParentId = C.ParentId
	GROUP BY C.ParentId
	)
	UPDATE U
	SET U.TotalQty = COALESCE(Summary.SumQty, 0)
	FROM dbo.Parent AS U
		INNER JOIN Changed ON
			U.ParentId = Changed.ParentId	
		LEFT OUTER JOIN Summary ON
			U.ParentId = Summary.ParentId

END
GO

INSERT INTO dbo.Parent (ParentId) VALUES
(1) , (2), (3), (4), (5), (6)

select * from Parent
select * from Child

INSERT INTO dbo.Child (ParentId, SEQ_NO, Qty) VALUES
(1, 1, 0),
(1, 2, 10),
(1, 3, 20),
(1, 4, 30),
(1, 5, 40),

(2, 1, 0),
(2, 2, 1),
(2, 3, 2),
(2, 4, 3),
(2, 5, 4)

select * from Parent
select * from Child

DELETE FROM dbo.Child WHERE ParentId = 1 AND SEQ_NO < 3

select * from Parent
select * from Child

UPDATE dbo.Child
SET aColumn = 10,
	Qty = Qty * 20
WHERE ParentId <= 2 AND SEQ_NO <= 3

select * from Parent
select * from Child