unix command using in awk

fla5do · #1 (**permalink**) 02-21-04, 11:35

Hi,
I want to execute a system call in awk and store the result in a awk variable. I get the result from the command, but not the output which is given from it.

for example :

awk ......
x=system("date")

I need a solution in awk !!! and not by using shell in this form :

DATE=´date´
awk -v DATE=$DATE .....

Thanx for your interest.

aigles · #2 (**permalink**) 02-21-04, 12:42

You can execute a command and read the result with 'getline' using the syntax :

Code:

command | getline [variable]

The following awk script read commands, execute them and print result.

Code:

awk '
function ExecCmde(cmde    ,line, result) {
   while ((cmde | getline line) > 0) {
      result = result (result=="" ? "" : "\n") line ;
   }
   return result;
}
tolower($1) ~ /exit|quit/ {
   exit;
}
NF>0 {
   print "===",$0,"===";
   print ExecCmde($0);
   print "===";
}
'

aigles · #3 (**permalink**) 02-22-04, 04:23

a little correction, add this line in the function before 'return'

Code:

close(cmde);

fla5do · #4 (**permalink**) 02-23-04, 16:40

Thanx aigles,
it is a very nice solution, and it works very fine when I type my "date" command followed by CR . Exit or quit ends the script. (wonderfull).
It is realy the way I want to do.
But I dont understand the source code . Is there an easier way, without typing the command. For example the "date" command as a fix text ???

Thanx a lot

aigles · #5 (**permalink**) 02-23-04, 16:57

For a command that return a signgle line (like 'date') command, you can do :

Code:

  "date" | getline the_date;
  close("date");  
print the_date;

# The same, with command in a variable
  date_cmde = "date +'%d.%m.%Y'";
  date_cmde | getline the_date;
  close(date);
  print the_date;

If your command return multiple line, you get them within a loop (like in my previous post) :

Code:

   while ((cmde | getline line) > 0) {
      print line;
   }
   close(cmde);

Damian Ibbotson · #6 (**permalink**) 02-24-04, 04:48

Peter,

You can also use the 'system' subroutine to explicitly call native utilities...

awk -v cmd=date 'BEGIN{system(cmd)}'

fla5do · #7 (**permalink**) 02-24-04, 13:49

Thanx Jean-Pierre,

it works well . Thank you for your interest to my problem.

Thanks Damian too, I have learn a lot with your comment.

but, when I try this :
awk -v cmd="date +%d%m%Y" 'BEGIN{
system(cmd)
x=system(cmd)
print x
}'

the printout from variable x, there is a second line with "0"

look at the output which is given :
24022004
24022004
0

aigles · #8 (**permalink**) 02-24-04, 15:12

when you use 'system' function to execute an external command, you don't get the output of the command. What you get is the status.

x=system(date)
execute the command, output goes to stdout, and x is set to status of command (0 for succes);

print x
print the status of the execution of the 'date' command.

if you want to retrieve the output of the command, you must use the 'command | getline' method.

Internet Services

Web Development

Digital Marketing

Consumer Tech